; $VER: Install LhADir 1.0 (27.5.95)
; Script to install LhADir.dopus5 1.0.
; Written by Edmund Vermeulen.

;=============================================================================
; check if Directory Opus 5 is already installed

(if (not (exists "DOpus5:DirectoryOpus" (noreq)))
    (abort "Directory Opus 5 must be installed first.")
)

;=============================================================================
; copy the files

(set @default-dest "DOpus5:arexx")

(copyfiles
   (source "arexx")
   (dest @default-dest)
   (pattern "#?")
   (files)
)

(copyfiles
   (source "filetypes/LHA archive")
   (dest "DOpus5:filetypes")
   (infos)
)

(copyfiles
   (source "buttons/LhADir Buttons")
   (dest "DOpus5:buttons")
)

(if
   (askbool
      (prompt "Install the LhADir toolbar?\n\n"
              "Your current toolbar will be renamed to 'toolbar_old'."
      )
      (help "By installing the LhADir toolbar you will be able to "
            "use the lister toolbar buttons for working on both normal "
            "directories and LhADir listed archives.\n\n"
            "The LhADir toolbar has the same functions as the default "
            "lister toolbar."
      )
   )
   (
      (rename "DOpus5:buttons/toolbar" "DOpus5:buttons/toolbar_old")
      (copyfiles
         (source "buttons/toolbar_LhADir")
         (dest "DOpus5:buttons")
         (newname "toolbar")
      )
   )
)

;=============================================================================
; install catalogs

(set catalogs
   (askoptions
      (prompt "Install selected catalog translations?")
      (help @askoptions-help)
      (choices "Nederlands")
      (default 0)
   )
)

(if (in catalogs 0)
   (copyfiles
      (source "Locale/Catalogs/nederlands/LhADir.catalog")
      (dest "LOCALE:Catalogs/nederlands")
   )
)

(exit)
